Создание дистрибутива Windows приложения в Inno Setup

Для удобства установки ваших программ на компьютеры пользователей вам понадобится создание дистрибутива. Сегодня я хочу рассказать об очень мощном и бесплатном инструменте для создания дистрибутивов для ОС Windows – Inno Setup.

Об Inno Setup

Inno Setup появившийся в 1997 году, сегодня соперничает с платными инсталляторами и даже превосходит многие из них по количеству функций и стабильности. Домашняя страница проекта находится здесь.

Вот ключевые возможности инсталлятора:

• • • Поддержка всех версий Windows, начиная с Windows 2000, включая: Windows 8, Windows Server 2012, Windows 7, Windows Server 2008 R2, Windows Vista, Windows Server 2008, Windows XP, Windows Server 2003 и Windows 2000. При этом никакие пакеты обновлений не требуются.
    • Обширная поддержка для установки 64-битных приложений на 64-битные версии Windows. Поддержка архитектур x64 and Itanium (если используется Windows Server 2003 на Itanium архитектуре, то требуется пакет обновлений 1 или более поздний для установки 64-битного режима работы).
    • Возможность создания дистрибутива, состоящего из одного единственного EXE-файла для удобного распространения в Интернете. Разбиение на диски также поддерживается.
    • Стандартный интерфейс мастера установки в стиле Windows 2000/XP.
    • Настраиваемые типы установки, такие как Полная, Компактная, Выборочная.
    • Широкие возможности деинсталляции.
    • Установка файлов: Включает интегрированную поддержку сжатия deflate, bzip2 и 7-Zip LZMA/LZMA2. Инсталлятор может сравнивать версии файлов, заменять используемые файлы, использовать подсчёт общих файлов, регистрировать DLL/OCX и библиотеки типов и устанавливать шрифты.
    • Создание ярлыков в любом месте, включая меню Пуск и рабочий стол.
    • Создание элементов реестра и INI-файлов.
    • Выполнение других программ до, во время и после установки.
    • Создание многоязычных дистрибутивов, включая языки с написанием слева направо.
    • Создание запароленных и зашифрованных дистрибутивов.
    • Поддержка цифровой подписи при установке и удалении.
    • Скрытая установка и удаление.
    • Поддержка Unicode.
    • Встроенный препроцессор для дополнительной настройки во время компиляции.
    • Встроенный обработчик скриптов Pascal для выполнения дополнительных действий во время установки и удаления.
    • Свободный исходный код (Borland Delphi 2.0-5.0 и 2009).

Большим плюсом Inno Setup является то, что его можно использовать абсолютно бесплатно даже для коммерческого использования. Хотя в качестве благодарности или для поддержки инсталлятора вы можете сделать пожертвование здесь. Там же есть список всех, кто пожертвовал от 100 долларов.

Вот как выглядит стартовая страница стандартного мастера установки дистрибутива созданного с помощью Inno Setup.

О создание дистрибутива в Inno Setup

Создание дистрибутива с помощью Inno Setup происходит следующим образом:

1. Сначала вы создаёте скрипт Inno Setup. Скрипт Inno Setup – это текстовый файл с расширением .iss, который содержит свойства дистрибутива и набор производимых действий при установке и удалении. Скрипт может быть создан с помощью стандартного редактора Inno Setup (см. картинку) или с помощью одного из сторонних редакторов, таких как Inno Script Studio или ISTool. В этой статье я рассмотрю использование только стандартного редактора Inno Setup.

2. Затем вы компилируете скрипт, получая при этом дистрибутив.
3. После компиляции вы можете тестировать и отлаживать полученный дистрибутив, выполняя инсталляцию и деинсталляцию.

Установка Inno Setup

Чтобы создавать дистрибутивы с помощью Inno Setup, достаточно установить компилятор Inno Setup к себе на компьютер. Дистрибутив можно скачать здесь. Ссылку на загрузку последней стабильной версии вы можете найти в секции Stable Release. На момент написания статьи последняя версия Inno Setup была 5.5.5, см. картинку. Чтобы скачать дистрибутив, нажмите на ссылку «Random site» напротив версии с поддержкой Unicode (файл isetup-5.5.5-unicode.exe) или без неё (ANSI версия – файл isetup-5.5.5.exe). Для избегания проблем с отображением кириллицы лучше сразу использовать Unicode-вариант Inno Setup.

Если вы собираетесь шифровать свой будущий дистрибутив, то модуль для шифрования ISCrypt.dll вам нужно скачать отдельно в секции Encryption Module, см. картинку (ниже вы видите ссылку на исходные коды этого модуля – ISCrypt.zip).

На этой же странице в секции QuickStart Pack вы можете найти ссылку на дистрибутивы ispack-5.5.5.exe и ispack-5.5.5-unicode.exe для установки Inno Setup вместе с Inno Script Studio, см. картинку. Inno Script Studio – это разработка сторонней компании (Kymoto Solutions), которая предлагает вам свой удобный пользовательский интерфейс и предоставляет возможность отладки вашего инсталлятора во время выполнения. Также, этот дистрибутив предложит скачать и установить модуль шифрования ISCrypt.dll автоматически.

Кроме всего перечисленного, на странице загрузки есть секции Beta Release, для загрузки бета версий Inno Setup, и Source Code, для загрузки исходных кодов, на которых я не буду заострять внимание.

Если вы собираетесь пользоваться более продвинутыми редакторами скрипта Inno Setup, то вам также будет интересна страница Inno Setup Third-Party Files со списком разработок сторонних компаний. Вот какие сторонние разработки мы можем использовать совместно с Inno Setup:

• • • Inno Script Studio – пользовательский интерфейс и отладчик. Устанавливается с помощью дистрибутива QuickStart Pack (см. выше) или отдельным дистрибутивом, который вы можете скачать с сайта разработчика. Есть русификация.

• • • Visual & Installer - платный плагин для Visual Studio (поддерживаются Visual Studio 2005, 2008, 2010, 2012 и 2013) для создания дистрибутивов с помощью Inno Setup. Также Visual & Installer содержит мастер Graphical Installer Wizard, позволяющий создавать тематически оформленные дистрибутивы (см. примеры здесь).

• • Inno Download Plugin – библиотека и скрипт Inno Setup, дающие возможность скачивать файлы в процессе установки вашего дистрибутива. Есть поддержка русского языка. Поддерживаются протоколы FTP, HTTP и HTTPS.

• • • InnoTools Downloader – ещё один вариант, похожий на Inno Download Plugin, тоже для загрузки файлов во время установки. Но здесь нет русификатора, и поддерживаются только FTP и HTTP.
    • VCL Styles for Inno Setup / ISSkin / Graphical Installer (последний инструмент платный) – инструменты для изменения оформления мастера установки вашего дистрибутива.

• • • InnoScript – автоматически создаёт файл скрипта Inno Setup (.iss) по файлу проекта Visual Basic (.vbp или .vbproj). Есть русификация.

• • • Inno Setup Toolbar Advanced for VB6 – создаёт дистрибутив для проекта Visual Basic из среды разработки Visual Basic 6.0.

• • • ISSComponentHelper – позволяет по файлу Delphi проекта (.dpr) или по файлу проекта библиотеки Delphi (.dpk) создать список зависимостей необходимый для создания дистрибутива. С проектом Delphi XE3 эта утилита у меня отказалась работать.
    • Inno Setup Script #Includes – библиотека функций, которые вы можете использовать при установке. Список функций можно посмотреть здесь.
    • Inno Setup Easy Translator – редактор языковых файлов Inno Setup (.isl). Этот сайт не работает с 2013 года, но расстраиваться не нужно, ведь вы можете легко создавать и редактировать языковые файлы в любом текстовом редакторе.
    • UninsHs – расширение, позволяющее добавить поддержку «Repair/Modify/Remove» в ваши приложения.

Ещё в этом списке, почему то нет ещё некоторых известных разработок (список обновлён 13.04.2015):

• • • ISTool – пользовательский интерфейс для работы со скриптом Inno Setup. Эта программа очень похожа на Inno Script Studio. Если поискать, то можно найти русификацию, см. картинку.

• • • InnoIDE – ещё один пользовательский интерфейс для работы со скриптом Inno Setup. Сайт InnoIDE перестал существовать примерно в августе 2012 года (www.innoide.org), поэтому использовать эту разработку не имеет смысла. Но сохранился архив сайта, который можно посмотреть здесь. Там же можно скачать дистрибутив. Русификацию для InnoIDE можно найти в Интернете.

• • • InnoSetup Script Joiner – утилита объединяющая несколько скриптов Inno Setup в один.
    • Innounp (Inno Setup Unpacker) - распаковщик дистрибутивов созданных с помощью Inno Setup. Консольное приложение.
    • InnoExtractor – ещё один распаковщик, но имеющий пользовательский интерфейс. Есть русификация. С моим зашифрованным тестовым дистрибутивом справился на-отлично (см. картинку). Как видите, достаёт абсолютно все файлы, в том числе и файлы используемые инсталлятором, и даже файл скрипта Inno Setup.

Собственно, после того как вы определились с необходимым функционалом, вы можете начинать установку. Здесь я рассмотрю лишь установку Inno Setup + Inno Script Studio с помощью пакета QuickStart Pack (файл ispack-5.5.5-unicode.exe). Хотя подробно расписывать все шаги нет смысла, остановлюсь лишь на некоторых. Галочка «Download and install Inno Script Studio» должна стоять, если вы хотите установить Inno Script Studio, галочка «Install Inno Setup Preprocessor» - чтобы установить препроцессор, галочка «Download and install encryption support» - чтобы установить модуль ISCrypt.dll для шифрования дистрибутива.

Первый запуск Inno Setup Compiler

Единственное окно программы Inno Setup – это окно компилятора. Компилятор запускается из меню «Пуск». При первом запуске вы увидите приглашение предлагающее создать пустой скрипт, запустить мастер создания скрипта или открыть примеры или последние использованные файлы.

Если у вас нет опыта общения с Inno Setup, то примеры будут кстати. Давайте откроем какой-нибудь пример, нажмите кнопку «OK» и выберите один из примеров. После того как пример открылся вы можете оценить, как выглядит простой скрипт Inno Setup. Также обратите внимание, что интерфейс компилятора очень прост и весь скрипт вам нужно будет писать вручную. В вашем распоряжении здесь будет только справка и примеры.

Использование мастера для создания скрипта Inno Setup

Создавать новый скрипт Inno Setup вы можете с чистого листа или можете воспользоваться мастером создания скрипта. Для примера я сделаю дистрибутив для установки программы MyProg.exe, которая находится в папке с примерами (устанавливается вместе с Inno Setup). При запуске программа выдаёт два окошка и завершается.

Чтобы вызвать окно мастера создания скрипта, щёлкните по пункту меню «File -> New» или в окне приветствия выберите опцию «Create a new script file using the Scrip Wizard» и нажмите «OK». Первый экран мастера будет с приветствием. Нажмите здесь «Next >».

На втором экране введите название приложения (Application name), версию приложения (Application version), издателя приложения (Application publisher) и адрес сайта приложения (Application website). Жирным шрифтом в мастере отмечены обязательные поля, а остальные можно сделать пустыми.

На следующем шаге вы выбираете папку для своего приложения. По умолчанию, как видно по картинке, это папка с тем же именем, что и имя приложения, и она будет создана внутри папки Program Files. Галочка «Allow user to change the application folder» позволит пользователю поменять папку в процессе установки. А при установке галки «The Application doesn’t need a folder» папка приложения вообще не будет создаваться.

Если из выпадающего списка «Application destination base folder» вы выберете «(Custom)», то в поле, находящемся чуть ниже, можно будет задать произвольный путь. Например, чтобы папка вашего приложения была на системном диске, нужно указать «{sd}».

Как видите, для указания системного диска я указал «{sd}» вместо «C:», ведь на разных компьютерах системный диск может быть разным. Вообще в Inno Setup вы будете очень часто использовать константы типа «{sd}». Все константы окружены фигурными скобками и их очень много. Вот полный список констант с кратким описанием (полное описание смотрите в разделе «Constants» в справке):

Константы директорий:

• • • {app} – директория приложения, например, «C:\Porgram Files\Моя Программа».
    • {win} – директория Windows, например, «C:\WINDOWS».
    • {sys} – директория System32, например, «C:\WINDOWS\SYSTEM».
    • {src} – директория, в которой находятся файлы дистрибутива (это временная папка с распакованными файлами дистрибутива).
    • {sd} – системный диск, например, «C:».
    • {pf} – директория приложений, например, «C:\Program Files (x86)» (в 64-битном режиме – это будет папка для 64-битных приложений). В 32-битном режиме эта константа эквивалентна константе {pf32}, а в 64-битном – {pf64}.
    • {cf} – папка общих файлов, например, «C:\Program Files (x86)\Common Files». В 32-битном режиме эта константа эквивалентна константе {cf32}, а в 64-битном – {cf64}.
    • {tmp} – временная папка, используемая при инсталляции или деинсталляции (имя папки будет в формате «C:\WINDOWS\TEMP\IS-xxxxx.tmp»).
    • {fonts} – папка шрифтов.
    • {dotnet11} – корневая папка .NET Framework 1.0.
    • {dotnet20} – корневая папка .NET Framework 2.0. В 32-битном режиме эта константа эквивалентна константе {dotnet2032}, а в 64-битном – {dotnet2064}.
    • {dotnet40} – корневая папка .NET Framework 4.0. В 32-битном режиме эта константа эквивалентна константе {dotnet4032}, а в 64-битном – {dotnet4064}.

Константы папок окружения:

• • • {group} – путь к папке меню «Пуск», доступной для всех пользователей.
    • {localappdata} – путь к локальной (без роуминга) папке Application Data.
    • {sendto} – путь к папке пользователя Send To.
    • {userappdata} и {commonappdata} – путь к папке Application Data.
    • {usercf} – путь к папке пользователя Common Files (работает только для Windows 7 и последующих версий, для старых версий Windows эта константа будет приравнена к {localappdata}\Programs\Common).
    • {userdesktop} и {commondesktop} * - путь к папке рабочего стола.
    • {userdocs} и {commondocs} – путь к папке «Мои документы» (My Documents).
    • {userfavorites} и {commonfavorites} * - путь к папке «Избранное» (Favorites).
    • {userpf} – путь к папке пользователя Program Files (работает только для Windows 7 и последующих версий, для старых версий Windows эта константа будет приравнена к {localappdata}\Programs).
    • {userprograms} и {commonprograms} * - путь к папке «Все программы» (Programs) в меню «Пуск».
    • {userstartmenu} и {commonstartmenu} * - путь к верхнему уровню меню «Пуск».
    • {userstartup} и {commonstartup} * - путь к папке «Автозагрузка» (Startup) в меню «Пуск».
    • {usertemplates} и {commontemplates} * - путь к папке «Шаблоны» (Templates).

* = константы «common» приравниваются к константам «user», если пользователю не хватает административных привилегий или инструкция PrivilegesRequired установлена в lowest.

Другие константы:

• • • {\} – используется в тех случаях, когда в конце пути нужно установить слеш, например, {app}{\}. В противном случае Inno Setup уберёт последний слеш.
    • {%NAME|DefaultValue} – значение переменной окружения, где NAME – имя переменной, DefaultValue – строка, которую нужно использовать, если переменной нет. DefaultValue – использовать необязательно. Примеры: {%COMSPEC} или {%PROMPT|$P$G}. Если в строке используются символы «,», «|», «}» или «%», то вместо них нужно писать «%2c», «%7c», «%7d» и «%25», соответственно.
    • {cmd} – полный путь к консоли, например, Windows\System32\cmd.exe (переменная окружения COMSPEC не используется для раскрытия этой константы).
    • {computername} – имя компьютера, на котором выполняется инсталляция или деинсталляция (значение возвращаемое функцией GetComputerName).
    • {drive:Path} – получает букву диска с двоеточием из произвольного пути. Если указан UNC-путь, то возвращает сервер и папку, например, \\SERVER\SHARE. Здесь также, чтобы написать символы «,», «|», «}» или «%», нужно писать «%2c», «%7c», «%7d» и «%25», соответственно. Вот примеры: {drive:{src}}, {drive:c:\path\file} или {drive:\\server\share\path\file}.
    • {groupname} – имя папки в меню «Пуск» для ваших пунктов меню, которую выбрал пользователь при инсталляции. В отличии от константы {group} возвращает только имя, а не полный путь.
    • {hwnd} – идентификатор фонового окна инсталлятора.
    • {wizardhwnd} – идентификатор окна мастера инсталлятора или 0, если идентификатор недоступен.
    • {ini:Filename,Section,Key|DefaultValue} – значение из INI-файла, где Filename – это имя INI-файла, Section – имя секции в INI-файле, Key – имя ключа в INI-файле, DefaultValue – строка которую нужно использовать, если указанный ключ не найден. Здесь также, чтобы написать символы «,», «|», «}» или «%», нужно писать «%2c», «%7c», «%7d» и «%25», соответственно. Пример: {ini:{win}\MyProg.ini,Settings,Path|{pf}\My Program}.
    • {language} – внутреннее имя выбранного языка.
    • {cm:MessageName} и {cm:MessageName,Arguments} – сообщение на текущем языке, где MessageName – имя сообщения, Arguments – аргументы для сообщения разделённые запятыми. Здесь также, чтобы написать символы «,», «|», «}» или «%», нужно писать «%2c», «%7c», «%7d» и «%25», соответственно. Пример: {cm:LaunchProgram,Inno Setup}.
    • {reg:HKxx\SubkeyName,ValueName|DefaultValue} – строка из реестра, где HKxx – корневой ключ реестра, SubkeyName – путь к нужному ключу, ValueName – имя значения (или пусто, если нужно считать значение по умолчанию для ключа), DefaultValue – строка которую нужно использовать, если указанного значения нет или значение не строка (REG_SZ или REG_EXPAND_SZ). Здесь также, чтобы написать символы «,», «|», «}» или «%», нужно писать «%2c», «%7c», «%7d» и «%25», соответственно. Пример: {reg:HKLM\Software\My Program,Path|{pf}\My Program}.
    • {param:ParamName|DefaultValue} – параметр переданный инсталлятору в командной строке, где ParamName – имя параметра, DefaultValue - строка которую нужно использовать, если указанный параметр не найден. Здесь чтобы написать символы «,», «|», «}» или «%», нужно писать «%2c», «%7c», «%7d» и «%25», соответственно. Пример: {param:Path|{pf}\My Program}.
    • {srcexe} – полный путь к инсталлятору, например, C:\SETUP.EXE.
    • {uninstallexe} – полный путь к деинсталлятору, созданному инсталлятором, например, C:\Program Files\My Program\unins000.exe. Эта константа обычно используется для создания ярлыка для удаления программы в секции [Icons] скрипта Inoo Setup. Константа действительна, только если инструкция Uninstallable установлена в yes.
    • {sysuserinfoname}, {sysuserinfoorg} – имя и организация, соответственно, на которые зарегистрирована Windows. Эта информация считывается из реестра.
    • {userinfoname}, {userinfoorg}, {userinfoserial} – имя, организация и серийный номер, соответственно, указанные пользователем на странице «Информация о пользователе» в мастере инсталлятора (которая может быть включена с помощью инструкции UserInfoPage). Обычно эта информация используется для записи в реестр или INI для дальнейшего использования.
    • {username} – имя пользователя запустившего инсталлятор или деинсталлятор (используется функция GetUserName).
    • {log} – имя файла журнала или пустая строка, если журналирование не включено.

Следующий шаг мастера создания скрипта Inno Setup позволяет добавить файлы вашего приложения.

В самом верхнем поле выбирается основной исполняемый файл. Если вы установите галку «Allow user to start the application after Setup has finished», то пользователь увидит предложение запустить приложение после установки. Если у вашего дистрибутива нет исполняемого файла, то вы можете установить галку «The application doesn’t have a main executable file». Ниже идёт список файлов для вашего дистрибутива. Здесь можно добавлять отдельные файлы (кнопка «Add file(s)…») или целые папки (кнопка «Add folder…»). При добавлении папки вы увидите дополнительный вопрос, включать подпапки или нет.

После добавления папок и файлов в список вы сможете редактировать каждый элемент (кнопка «Edit…») или удалить его (кнопка «Remove»). В окне редактирования вы сможете поменять многие параметры: нужно ли рекурсивно включать подпапки (галка «Recurse subfolders»), нужно ли включать пустые папки (галка «Include empty subfolders»), базовая папка назначения (поля «Destination base folder») и папка внутри базовой папки назначения («Destination subfolder»).

Мы для примера добавим только файл справки.

Следующий шаг мастера – это выбор создаваемых иконок. В поле «Application Start Menu folder name» задаётся имя группы в меню «Пуск». Если вы установите галку «Allow user to change the Start Menu folder name», то пользователь сможет поменять имя папки во время установки, а если вы установите галку «Allow user to disable Start Menu folder creation», то пользователь сможет вообще отключить создание этой папки в меню «Пуск». Установите галку «Create an Internet shortcut in the Start Menu folder» и «Create an Uninstall icon in the Start Menu folder» чтобы инсталлятор создал ярлыки внутри группы, соответственно, для открытия вашего сайта и для удаления вашего приложения. Галочки «Allow user to create a desktop icon» и «Allow user to create a Quick Launch icon» позволят пользователю создать ярлыки на рабочем столе и в группе быстрого запуска. Я поставлю все галочки.

На следующем шаге задаются файлы лицензии (License file) и файлы с информацией, которые будут показаны до и после установки. Если вы указали файл лицензии, то при инсталляции, пользователь должен будет согласиться с лицензией. Поддерживаются файлы .txt и .rtf. Я укажу файлы license.txt и Readme.txt из папки с примерами.

На следующем шаге выбираем поддерживаемые языки. Я оставлю английский и добавлю русский.

На следующем шаге задаются параметры для компилятора Inno Setup. В поле «Custom compiler output folder» задаётся путь к папке, в которую компилятор Inno Setup будет сохранять созданный дистрибутив. Если в этом поле пусто, то дистрибутив будет создаваться в той же папке, что и файл .iss. В поле «Compiler output base file name» задаётся базовое имя для файла или файлов дистрибутива. Например, если у вас задано имя «setup», то при создании дистрибутива, состоящего из одного файла, вы получите файл setup.exe. В поле «Custom Setup icon file» вы можете указать имя файла иконки для будущего дистрибутива. Если здесь ничего не указано, то будет использоваться стандартная иконка. В последнем поле «Setup Password» вы можете указать пароль, который пользователь должен будет указать при инсталляции. Если установлена галка «Use the password to encrypt the application files», то с помощью указанного пароля будут зашифрованы файлы, находящиеся в дистрибутиве. Я для примера заполню все поля по-своему.

Следующий шаг оповещает вас о том, что обнаружен препроцессор Inno Setup и предлагает использовать директивы #define для упрощения вашего скрипта. Если вы хотите использовать директиву #define, оставьте галочку «Yes, use #define compiler directives». Если галочка не установлена, то, в дальнейшем, вы сможете добавить директивы #define в свой скрипт вручную.

И наконец-то появился последний шаг, где мы просто нажимаем на кнопку «Finish».

После этого компилятор сразу хочет скомпилировать наш скрипт. Давайте согласимся и нажмём кнопку «Да».

После этого компилятор предупредит нас, что скрипт не сохранён и предложит сделать это.

Давайте согласимся (нажмём «Да») и сохраним скрипт. После сохранения скрипт скомпилировался и готовый дистрибутив, в примере это файл my-setup.exe, создался в папке, которую я указал в мастере на шаге «Compiler Settings». После компиляции вы можете посмотреть, как она прошла на панели «Compiler Output» внизу окна компилятора, см. картинку.

Как видите всё просто. Теперь сразу протестируем готовый дистрибутив. Щёлкните по пункту меню «Run -> Run», чтобы запустить установку программы.

После создания заготовки скрипта, вы можете приступить к добавлению различных продвинутых действий.

Отладка дистрибутива в Inno Setup

Для отладки вашего дистрибутива, откройте скрипт .iss и щёлкните по пункту меню «Run -> Run», чтобы запустить установку программы. После этого вы сможете отслеживать внутренние процессы во время инсталляции в окне «Debug Output», сможете ставить точки останова на нужных строках, см. картинку.

Чтобы проверить значение константы, во время отладки, щёлкните по пункту меню «Run -> Evaluate Constant…» и в поднявшемся диалоге укажите имя константы (см. картинку) и нажмите «ОК».

После этого появится следующее окошко с результатом, который вернула константа.

Чтобы отладить деинсталляцию, щёлкните по пункту меню «Run -> Target Uninstall», а затем «Run -> Run». А для возврата обратно к инсталляции, щёлкните по пункту «Run -> Target Setup».

Структура скрипта Inno Setup

Скрипты в Inno Setup разбиты на секции. Имя каждой секции заключено в квадратные скобки. Внутри каждой секции содержатся специфические для этой секции элементы. Для удобства вы можете делать несколько секций с одинаковым именем. Такие секции будут восприниматься как одна. Вот пример:

[Setup]
AppName=My Program
 
[Files]
Source: "MYPROG.EXE"; DestDir: "{app}"

Вы можете комментировать строки, чтобы их игнорировал компилятор, установкой вначале точки с запятой.

; Это комментарий. Здесь можно оставить напоминалку для себя...

В скрипте поддерживается C-подобная директива #include, заставляющая компилятор втягивать строки из указанного произвольного текстового файла, в то место где эта директива стоит. Вот синтаксис:

#include "filename.txt"

С помощью директивы #preproc вы можете указать, какой препроцессор следует использовать: встроенный, поддерживающий только директиву #include, или Inno Setup Preprocessor (ISPP), который поддерживает очень много директив и функций. По умолчанию в скриптах используется препроцессор ISPP, если он установлен, а в файлах .isl используется встроенный препроцессор. Вот синтаксис:

#preproc builtin
#preproc ispp

Секции скрипта Inno Setup

Приведу здесь полный список всех секций Inno Setup с кратким описанием. Полное описание секций и список элементов секций можно найти в справке в разделе «Setup Script Sections».

[Setup] – эта секция содержит глобальные настройки, используемые при инсталляции и деинсталляции. Пример:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DefaultGroupName=My Program

[Types] – необязательная секция, определяющая варианты установки (Полная/Компактная/Выборочная), которые будут отображаться на странице выбора компонентов для установки. Пример:

[Types]
Name: "full"; Description: "Full installation"
Name: "compact"; Description: "Compact installation"
Name: "custom"; Description: "Custom installation"; Flags: iscustom

[Components] – необязательная секция, определяющая компоненты, которые будут отображаться на странице выбора компонентов для установки. Пример:

[Components]
Name: "main"; Description: "Main Files"; Types: full compact custom; Flags: fixed
Name: "help"; Description: "Help Files"; Types: full
Name: "help\english"; Description: "English"; Types: full
Name: "help\dutch"; Description: "Dutch"; Types: full

[Tasks] – необязательная секция, для создания дополнительных заданий, выполняемых при инсталляции. Пользователь будет видеть задания в виде переключателей и сможет выбирать выполнять то или иное задание или нет. Пример:

[Tasks]
Name: desktopicon; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"; Components: main
Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Components: main; Flags: exclusive
Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Components: main; Flags: exclusive unchecked
Name: quicklaunchicon; Description: "Create a &Quick Launch icon"; GroupDescription: "Additional icons:"; Components: main; Flags: unchecked
Name: associate; Description: "&Associate files"; GroupDescription: "Other tasks:"; Flags: unchecked

[Dirs] – эта необязательная секция определяет, какие дополнительные папки, кроме папки приложения, нужно создавать.

[Dirs]
Name: "{app}\data"
Name: "{app}\bin"

[Files] – необязательная секция, определяющая, какие файлы будут устанавливаться на компьютер.

[Files]
Source: "CTL3DV2.DLL"; DestDir: "{sys}"; Flags: onlyifdoesntexist uninsneveruninstall
Source: "MYPROG.EXE"; DestDir: "{app}"
Source: "MYPROG.CHM"; DestDir: "{app}"
Source: "README.TXT"; DestDir: "{app}"; Flags: isreadme

[Icons] – необязательная секция, определяющая, какие будут создаваться ярлыки в меню «Пуск», на рабочем столе и т.д.

[Icons]
Name: "{group}\My Program"; Filename: "{app}\MYPROG.EXE"; WorkingDir: "{app}"
Name: "{group}\Uninstall My Program"; Filename: "{uninstallexe}"

[INI] – необязательная секция, определяющая, какие записи будут добавлены в INI-файл.

[INI]
Filename: "MyProg.ini"; Section: "InstallSettings"; Flags: uninsdeletesection
Filename: "MyProg.ini"; Section: "InstallSettings"; Key: "InstallPath"; String: "{app}"

[InstallDelete] и [UninstallDelete] - эти необязательные секции определяют, какие файлы или папки нужно удалить, соответственно, при первой инсталляции или деинсталляции. Пример:

[UninstallDelete]
Type: files; Name: "{win}\MYPROG.INI"

[Languages] – секция определяет языки, которые будут доступны при инсталляции. При запуске инсталлятора будет подобран язык, совпадающий с языком системы. В ином случае по умолчанию будет использоваться язык находящийся первым в секции [Languages]. Пример:

[Languages]
Name: "en"; MessagesFile: "compiler:Default.isl"
Name: "nl"; MessagesFile: "compiler:Languages\Dutch.isl"

[Messages] – секция для замены сообщений, описанных в языковых файлах .isl. Пример замены стандартного текста «&Next >» на кнопке перехода на следующий шаг только для английского языка:

[Messages]
en.ButtonNext=&Forward >

[CustomMessages] – секция для определения значений константы {cm:...}, см. описание констант выше. Пример использования:

[CustomMessages]
CreateDesktopIcon=Create a &desktop icon
 
[Tasks]
Name: desktopicon; Description: "{cm:CreateDesktopIcon}"

[LangOptions] – секция содержит настройки языка, такие как шрифт. Пример:

[LangOptions]
LanguageName=English
LanguageID=$0409
LanguageCodePage=0
DialogFontName=
DialogFontSize=8
WelcomeFontName=Verdana
WelcomeFontSize=12
TitleFontName=Arial
TitleFontSize=29
CopyrightFontName=Arial
CopyrightFontSize=8
RightToLeft=no

[Registry] – эта необязательная секция определяет, какие ключи и значения нужно создать, изменить или удалить в реестре. Примеры использования:

[Registry]
Root: HKCU; Subkey: "Software\My Company"; Flags: uninsdeletekeyifempty
Root: HKCU; Subkey: "Software\My Company\My Program"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\My Company"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\My Company\My Program"; Flags: uninsdeletekey
Root: HKLM; Subkey: "Software\My Company\My Program\Settings"; ValueType: string; ValueName: "InstallPath"; ValueData: "{app}"

[Run] – эта необязательная секция определяет, какие программы нужно выполнить после успешной установки, но до появления финишного шага в окне мастера установки. Примеры:

[Run]
Filename: "{app}\INIT.EXE"; Parameters: "/x"
Filename: "{app}\README.TXT"; Description: "View the README file"; Flags: postinstall shellexec skipifsilent
Filename: "{app}\MYPROG.EXE"; Description: "Launch application"; Flags: postinstall nowait skipifsilent unchecked

[UninstallRun] – эта необязательная секция определяет, какие программы нужно выполнить в самом начале деинсталляции.

[Code] – в этой необязательной секции вы можете разместить свой Pascal-скрипт. Для обработки Pascal-скрипта используется движок RemObjects Pascal Script. Этот движок так же бесплатен, как и Inno Setup. Официальная страница движка RemObjects Pascal Script - здесь. Примеры использования можно найти в файлах «Code*.iss» и «UninstallCode*.iss» в папке «Examples» в месте установки Inno Setup.

Порядок инсталляции и деинсталляции

Очень важный момент при инсталляции – это понимание, в каком порядке происходит выполнение скрипта. Ниже перечислены действия инсталлятора в том порядке, в котором они будут выполняться при установке:

• • • Выполнение секции [InstallDelete].
    • Элементы секции [UninstallDelete] сохраняются в журнале деинсталляции (который, на этом этапе хранится в памяти).
    • Создаётся директория приложения, если необходимо.
    • Выполняется секции [Dirs].
    • Резервируется имя файла журнала деинсталляции, если необходимо.
    • Выполняется секция [Files] (регистрация файлов пока не производится).
    • Выполняется секция [Icons].
    • Выполняется секция [INI].
    • Выполняется секция [Registry].
    • Файлы, которые должны регистрироваться, регистрируются, за исключением случая, когда система должна быть перезагружена. В случае, когда требуется перезагрузка, регистрация происходит только после рестарта системы.
    • Добавление в список установленных программ (Панель управления\Программы\Программы и компоненты), если необходимо.
    • Элементы секции [UninstallRun] сохраняются в журнал деинсталляции.
    • EXE-файл и журнал деинсталлятора сохраняются на диск. После этого момента, пользователю запрещена отмена установки, и любые последующие ошибки не приведут к откату установки.
    • Выполнение секции [Run], кроме элементов секции с установленным флагом «postinstall», которые будут выполнены после отображения последнего шага мастера установки.
    • Обновление ассоциаций для файлов, если флаг «ChangesAssociations» установлен в «yes».
    • Оповещение выполняемых приложений о том, что переменные окружения изменились, если флаг «ChangesEnvironment» установлен в «yes».
    • Что касается элементов секции, то они будут выполняться в том порядке, в котором они расположены внутри секции.

Деинсталляция происходит в обратном порядке. Но это не касается секций [UninstallRun] и [UninstallDelete], которые будут выполняться в том порядке, в котором они встречаются в скрипте (не в обратном порядке).

Препроцессор Inno Setup

Пару слов хочется написать о препроцессоре Inno Setup (ISPP). Основная задача препроцессора – это автоматизация задач во время компиляции и снижение вероятности опечатки в ваших скриптах. Например, вы можете объявить переменную ISPP (переменная времени компиляции), содержащую имя вашего приложения, а затем использовать значение этой переменной в нескольких местах вашего скрипта. Если в дальнейшем по какой-то причине вы должны изменить имя вашего приложения, вы сможете сделать это в одном месте вашего скрипта. Без ISPP, вам придётся найти и исправить все части скрипта, где вы используете имя приложения, например, AppName, AppVerName, DefaultGroupName и т.п.

Другой пример использования ISPP – это вытягивание информации о версии приложения из ЕХЕ-файла и использование её в инструкции AppVerName в секции [Setup]. Без ISPP, вам придется менять скрипт каждый раз при изменении версии приложения.

Кроме того, разбиение скрипта на части, даёт возможность создать единый скрипт для разных версий вашего приложения (например, пробная и полнофункциональная версии).

При использовании препроцессора важно помнить, что препроцессор работает только во время компиляции.

Вызов компилятора Inno Setup из командной строки

Не лишним будет знать и о возможности компиляции дистрибутива из командной строки. Вызов компиляции выглядит следующим образом:

compil32 /cc <script name>

А вот пример:

compil32 /cc "c:\isetup\samples\my script.iss"

Вызов компиляции из командной строки, в данном случае, не скрывает отображение прогресса или сообщений об ошибках. Компилятор возвращает 0, если компиляция прошла успешно, 1, если параметры командной строки переданы неверно, или 2, если компиляция не удалась.

Альтернативный способ компиляции – это использование консольного компилятора ISCC.exe. Вот схема использования компилятора:

iscc [options] <script name>

А вот пример:

iscc "c:\isetup\samples\my script.iss"

Вот основные опции:

/DO – отключить создание дистрибутива (меняет все параметры Output в скрипте).
/EO – включить создание дистрибутива (меняет все параметры Output в скрипте).
/O – устанавливает путь, где будет создан дистрибутив (меняет все параметры OutputDir в скрипте).
/F – устанавливает имя файла дистрибутива (меняет все параметры OutputBaseFilename в скрипте).
/S – настройка параметра SignTool.
/Q[p] – для скрытой компиляции (выводятся только сообщения об ошибках, «p» выводит прогресс).
/? – для отображения справки.

Вот пример с использованием опций:

iscc /Qp /O"My Output" /F"MyProgram-1.0" /Sbyparam=$p "c:\isetup\samples\my script.iss"

ISCC возвращает 0, если компиляция прошла успешно, 1, если неправильно указаны параметры или произошла внутренняя ошибка, или 2, если компиляция не удалась.

В заключении об Inno Setup

Рассказать обо всех возможностях Inno Setup не удастся в рамках одной статьи, это очень большой объём информации, поэтому я описал здесь лишь основные моменты. После прочтения вы сможете начать пользоваться этим замечательным инструментом для создания собственных дистрибутивов. В будущем я расскажу про альтернативные пользовательские интерфейсы. А сейчас, пишите ваши комментарии к статье, и я постараюсь ответить на все ваши вопросы.